cs1s2.f

Go to the documentation of this file.

      SUBROUTINE cs1s2(ZR, S1, S2, NZ, ASCLE, ALIM, IUF)
C***BEGIN PROLOGUE  CS1S2
C***REFER TO  CBESK,CAIRY
C
C     CS1S2 TESTS FOR A POSSIBLE UNDERFLOW RESULTING FROM THE
C     ADDITION OF THE I AND K FUNCTIONS IN THE ANALYTIC CON-
C     TINUATION FORMULA WHERE S1=K FUNCTION AND S2=I FUNCTION.
C     ON KODE=1 THE I AND K FUNCTIONS ARE DIFFERENT ORDERS OF
C     MAGNITUDE, BUT FOR KODE=2 THEY CAN BE OF THE SAME ORDER
C     OF MAGNITUDE AND THE MAXIMUM MUST BE AT LEAST ONE
C     PRECISION ABOVE THE UNDERFLOW LIMIT.
C
C***ROUTINES CALLED  (NONE)
C***END PROLOGUE  CS1S2
      COMPLEX CZERO, C1, S1, S1D, S2, ZR
      REAL AA, ALIM, ALN, ASCLE, AS1, AS2, XX
      INTEGER IUF, NZ
      DATA czero / (0.0e0,0.0e0) /
      nz = 0
      as1 = cabs(s1)
      as2 = cabs(s2)
      aa = REAL(S1)
      aln = aimag(s1)
      IF (aa.EQ.0.0e0 .AND. aln.EQ.0.0e0) GO TO 10
      IF (as1.EQ.0.0e0) GO TO 10
      xx = REAL(ZR)
      aln = -xx - xx + alog(as1)
      s1d = s1
      s1 = czero
      as1 = 0.0e0
      IF (aln.LT.(-alim)) GO TO 10
      c1 = clog(s1d) - zr - zr
      s1 = cexp(c1)
      as1 = cabs(s1)
      iuf = iuf + 1
   10 CONTINUE
      aa = amax1(as1,as2)
      IF (aa.GT.ascle) RETURN
      s1 = czero
      s2 = czero
      nz = 1
      iuf = 0
      RETURN
      END